Turkish music has a wider variety of sounds compared to Western music. Not only musical instruments allow to play more pitches, but thanks to the lack of a de facto standardization (despite efforts in this direction), there is still a large degree of diverseness of sounds also when considering the same instrument.
We first review Turkish music temperament, and then play some scale using a software library.
First, some basic notion. Let's consider a note as a sinusoidal signal at a fixed frequency. The signal can be generated, e.g., by pitching the string of a stringed musical instrument. If the length of the string is halved (e.g., by pressing a guitar fret at its string half-length) the note generated is said to correspond to an octave of the base one (this terminology originates from the Western tradition, where there are eight tones to close an octave, e.g., C-D-E-F-G-A-B-C). Respectively, the frequency of the note doubles. Hence, an octave is denoted with the ratio 2:1 (respective to the reference note). Given two frequencies f0 and fn, they differ by no octaves if
fn/f0 = 2no.
One way to tune a musical instrument is to consider an equal temperament system. If we divide an octave into a number ntones of micro-tones equally spaced in frequency, the frequency of the note lying n micro-tones higher than the reference f0 is:
fn = 2n/ntones * f0.
A typical value for the reference frequency is the A4 note:
f0 = 440 Hz.
Most Western music instruments are nowadays tuned based on a 12-tone equal temperament system, where ntones=12. Hence, there are 12 intervals in an octave (which corresponds to, e.g., 13 guitar or piano frets).
Turkish music uses different temperament systems. Standardization efforts at the beginning of the 20th century lead to the Arel-Ezgi-Uzdilek (AEU) system. It is based on a 24-tone Pythagorean temperament, in which all of the tones are produced by repeatedly multiplying the reference frequency by the 3:2 ratio, called a fifth (from the fifth tone in the diatonic scale C D E F G...). A chain of pure fifths looks like 0, 3:2, 32:22, 33/23, ... corresponding to the frequency ratios 1/1, 3/2, 9/4, 27/8... . Multiplying by itself the fifth ratio 3:2 will never give exactly the same result as multiplying by itself an octave ratio 2:1. Even though the result can be pretty close (e.g., (3/2)12=129.7... and 27=128), the Pythagorean system does not close as equal tempered schemes: generating tones via circle of fifths misses the octave of the starting point. The AEU system is based on a chain of pure fifths, but closing the octave .
While the AEU system is acknowledged as a standardized theoretical framework, the practice faces many variations on it. For instance, the 24-tone Pythagorean model can be well approximated by a 53-tone equal temperament. Dividing an octave into 53 equal intervals known as commas, the 24-tone AUE system is commonly approximated by assigning 9 commas per whole tone, picking only the appropriate commas (see figure 6 of , or here for a representation of the AEU notes).
Not all Turkish music instruments include the entire AEU system. For instance, bağlamas (long-necked lutes) feature 17 intervals in an octave (18 frets). Traditional tuning is based on empirical rules (reference  gives a detailed interesting description—text in Turkish); tone ratios are presented in the next section. However, due to the increasing prevalence of the bağlama in contemporary music production, performers also set the frets according to a 24-equal tempered system, that plays better together with the Western tone system . Other variations are possible, e.g., some performer may use additional frets to the traditional ones.
The lack of a common tuning system may indeed make it challenging to play together several different instruments. However, while Western music tends to be harmonic (several instruments play together, often using chords), traditional Turkish music is melodic (one main instrument plays single notes).
Lacking a musical instrument tempered according to Turkish systems, we can generate sinusoidal signals using a software library.
Here we describe how to set up the software to play with a computer the pitches listed in the next section.
We'll use Racket, a dialect of the Scheme family of programming languages. Scheme is one of the simplest, yet most powerful programming languages conceived up to today. The choice of Racket among other possible interpreters is due to its user-friendly development environment, DrRacket, and to a handy library for sound manipulation, RSound. Use Racket package manager to install the library:
raco pkg install rsound
The main procedures that we use from the Rsound library are play, to play a sound, and make-tone, to define a sinusoidal wave with a given frequency. Let's first define some simple abstraction barrier around these procedures. We assume the following definitions in the code:
Here follow the basic procedures that we'll use to play scales of notes.
#lang racket (require rsound) ; Play in order a list of frequencies (Hz). (define (play-freqs freqs) (define (play-tone freq) ; Set the number of frames to the frame rate, so ; that the sound will last one unit of time (1s). (play (make-tone freq 1.0 FRAME-RATE)) ; Wait for a sound to finish (1s) before playing ; the following one. (sleep 1)) (map play-tone freqs)) ; Access the frequency corresponding to a given number of ; tones from the base frequency (default 440 Hz). Assume ; equal temperament and ntones per octave. (define (tone->freq n ntones (base-freq 440)) (* base-freq (expt 2 (/ n ntones)))) ; Access the frequency corresponding to a given note. (define (note->freq note pitches) (define (fmt-freq freq) (if (exact? freq) (exact->inexact freq) freq)) (define (note-iter lst) (cond [(null? lst) (error "note not found")] [(member note (car lst)) (fmt-freq (cadar lst))] [else (note-iter (cdr lst))])) (note-iter pitches)) ; Convert a list of notes to a list of frequencies. (define (scale->freqs scale pitches) (map (lambda (note) (note->freq note pitches)) scale)) ; Play a list of notes. (define (play-scale scale pitches) (play-freqs (scale->freqs scale pitches)))
Let's define Western pitches based on the 12-tone equal temperament system.
(define PITCHES-WEST (let* ([ntones 12] [tone (lambda (n) (tone->freq n ntones))]) `((A4 ,(tone 0)) (A4# ,(tone 1)) (B4b ,(tone 1)) (B4 ,(tone 2)) (C5 ,(tone 3)) (C5# ,(tone 4)) (D5b ,(tone 4)) (D5 ,(tone 5)) (D5# ,(tone 6)) (E5b ,(tone 6)) (E5 ,(tone 7)) (F5 ,(tone 8)) (F5# ,(tone 9)) (G5b ,(tone 9)) (G5 ,(tone 10)) (G5# ,(tone 11)) (A5b ,(tone 11)) (A5 ,(tone 12)))))
There are a total of 13 different notes (12 intervals). Flat and sharp symbols lower or rise a pitch by the same ratio so, e.g., A4♯ corresponds to the same frequency as B4♭.
Let's play a major scale, and the chromatic one based on the Western system.
(define scale-major '(A4 B4 C5 D5 E5 F5 G5 A5)) (play-scale scale-major PITCHES-WEST) (define scale-chromatic-west '(A4 A4# B4 C5 C5# D5 D5# E5 F5 F5# G5 G5# A5)) (play-scale scale-chromatic-west PITCHES-WEST)
To have an idea about how the richer Turksih sound systems sounds like, we consider bağlama pitches, since this is one of the most recurrent and characteristic instruments (other instruments worth mentioning are ney flutes, and the kanun—an impressive string instrument). Bağlama actually identifies a family of instruments characterized by different body and neck lengths. All types usually have three groups of chords. We consider the so called uzun sap (long neck) bağlama. A typical tuning for the three groups of strings is G-D-A (top to bottom). Different tunings are possible, and it is also common to scale the pitches by some ratio and still refer to the note names as G-D-A. (For instance, one may use a A#-F-C tuning where ratios among the three notes are the same as for G-D-A, and still refer to the notes as G-D-A. Apart from the different sound, another reason for a different tuning is that it may be easier to play a given piece if the strings are tuned to a higher or software tension. This is standard practice among guitar players, too.)
Here we consider the traditional temperament for the bağlama as listed in  (see page 159). We also add the G4 note outside the A4-A5 octave for later convenience.
(define PITCHES-BAGLAMA (let* ([base 440] [tonerat (lambda (rat) (* base rat))]) `((G4 ,(tonerat (/ 16/9 2))) ; Outside A4-A5 octave. (A4 ,(tonerat 1/1)) (B4b ,(tonerat 18/17)) (B4b2 ,(tonerat 12/11)) (B4 ,(tonerat 9/8)) (C5 ,(tonerat 81/68)) (C5#3 ,(tonerat 27/22)) (C5# ,(tonerat 81/64)) (D5 ,(tonerat 4/3)) (E5b ,(tonerat 24/17)) (E5b2 ,(tonerat 16/11)) (E5 ,(tonerat 3/2)) (F5 ,(tonerat 27/17)) (F5#3 ,(tonerat 18/11)) (F5# ,(tonerat 27/16)) (G5 ,(tonerat 16/9)) (A5b ,(tonerat 32/17)) (A5b2 ,(tonerat 64/33)) (A5 ,(tonerat 2/1)))))
There are more notes than in the Western systems. (Also in the bağlama system the flat and sharp symbols may be used to indicate a same frequency as in the Western system, but for clarity here we do not list pitches with the same frequency.) For instance, between the tones A4 and B4 we have the semi-tones B4♭ and B4♭2, and between the tones C5 and D5 we have C5♯3 and C5♯ (we use conventional bağlama notation). Also, because of the different temperament, the same symbol in the Western and Turkish systems may refer to different frequencies.
(note->freq 'B4b PITCHES-WEST) ;#| 466.1637615180899 |# (note->freq 'B4b PITCHES-BAGLAMA) ;#| 465.88235294117646 |#
(Humans can distinguish such a small difference when playing together for a few seconds the two notes.)
To untrained ears it may appear that the chromatic scale picks up the "wrong" notes.
(define scale-chromatic-baglama '(A4 B4b B4b2 B4 C5 C5#3 C5# D5 E5b E5b2 E5 F5 F5#3 F5# G5 A5b A5b2 A5)) (play-scale scale-chromatic-baglama PITCHES-BAGLAMA)
However, the scale provides rich composition systems. Turkish music is based on makam's that are not only sets of notes (as Western scales) but also, at the same time, composition guidelines. Here we simply play in sequence the notes characterizing a few of the several makams listed in the literature, ignoring composition rules.
; This makam is similar to a Western A-harmonic minor ; scale. (define scale-buselik '(A4 B4 C5 D5 E5 F5 A5b A5)) (play-scale scale-buselik PITCHES-BAGLAMA) ; Some makam have different notes whether ascending or ; descending the scale . (define scale-rast '(G4 A4 B4b2 C5 D5 E5 F5# G5 G5 F5 E5 D5 C5 B4b2 A4 G4)) (play-scale scale-rast PITCHES-BAGLAMA) (define scale-ussak '(A4 B4b C5 D5 E5 F5 G5 A5)) (play-scale scale-ussak PITCHES-BAGLAMA)
One of the most characterizing notes of Turkish music is the 12:11 ratio, also called Segâh (every note has a different name in the traditional system, with no name repetitions among different octaves). If the base note as A4 as above, this corresponds to B4♭2. Here we play in sequence the initial notes of Uzun İnce Bir Yoldayım, a song by Âşık Veysel (a highly regarded Turkish bard) that is an example where the Segâh (B4♭2) has a prominent role. As before, we simply list the notes, neglecting the actual composition.
(define scale-uzun-ince '(C5 D5 D5 C5 B4b2 A4 C5 B4b2 B4b2 G4 B4b2 A4 A4)) (play-scale scale-uzun-ince PITCHES-BAGLAMA)
Let's compare bağlama tones with the AEU system (this image justifies the notation used below). Here we define and play the microtones between A4 and A5 (ratios are listed, e.g., in [1-2]).
(define PITCHES-AEU (let* ([base 440] [tonerat (lambda (rat) (* base rat))]) `((A4 ,(tonerat 1/1)) (B4b-- ,(tonerat 246/243)) (B4b ,(tonerat 2187/2048)) (A4# ,(tonerat 65536/59049)) (B4 ,(tonerat 9/8))))) (define scale-aeu-chromatic '(A4 B4b-- B4b A4# B4)) (play-scale scale-aeu-chromatic PITCHES-AEU)
The ratios 2187:2048 and 65536:59049 are rarely used and generally believed to sound unpleasant .